Split-plot設計 SAS實踐

• • • 試驗資源的限制
    • 第一種統計模型
    • • GLM procedure
      • Mixed procedure
    • 第二種統計模型
    • • GLM procedure
      • Mixed procedure

Split-plot設計有兩大難點，第一個難點是判斷什么時候用split-plot設計；第二個難點是判斷哪些效應可以省略。某造紙廠工程師試圖研究如何提高紙張的抗拉強度，為此他選擇了3種紙漿制備方法、完成每種方法時分別使用四種不同的溫度，重復試驗三次，一共需要試驗36組。受制備中間程序限制，每天只能完成12組試驗，他打算以每一天作為一個block，分三天完成試驗。下面是試驗數據：

data paper; input block method temp resp@@; datalines; 1 1 1 30 1 1 2 35 1 1 3 37 1 1 4 36 1 2 1 34 1 2 2 41 1 2 3 38 1 2 4 42 1 3 1 29 1 3 2 26 1 3 3 33 1 3 4 36 2 1 1 28 2 1 2 32 2 1 3 40 2 1 4 41 2 2 1 31 2 2 2 36 2 2 3 42 2 2 4 40 2 3 1 31 2 3 2 30 2 3 3 32 2 3 4 40 3 1 1 31 3 1 2 37 3 1 3 41 3 1 4 40 3 2 1 35 3 2 2 40 3 2 3 39 3 2 4 44 3 3 1 32 3 3 2 34 3 3 3 39 3 3 4 45 ; run;

試驗資源的限制

在用這個例子介紹Split-plot試驗的分析方法之前，我們可以總結一下Split-plot設計的適用范圍。隨機效應與混合效應模型是因子交叉設計的分析方法，當試驗經費不足，為了節約試驗資源的時候可以使用nested design，但如果是試驗資源的限制，就只能使用split-plot design了，常見的試驗資源限制有兩種：時間限制與空間限制，造紙的試驗是時間限制。

在介紹裂區設計的博客中，我介紹了另一個例子（空間限制）：要研究肥料對水稻的產量影響，考慮6種不同的水稻品種與4種不同的肥料，重復試驗3次（也被叫做3個blocking）；按交叉設計的思路，一共需要$6\times 4\times 3=72$塊地，假設每平方米種25墩，每墩插4株，每一個試驗單位為500株，則一共需要$72\times 500/(4\times 25)=360$平方米的試驗田；如果實驗室的試驗田只有180平方米，那就可以考慮裂區設計，把試驗田平均分為3部分（field），用來做3次重復試驗，每部分面積為60平方米，然后把3部分每一部分平均分成4大塊地（whole-plots），每一部分中每一塊地隨機施一種肥料，每塊地施的肥料各不相同，將每一大塊地平均分為6小塊（sub-plots），每一大塊地中每一小塊隨機種一種水稻，每塊地種的水稻各不相同。盡管這樣每一小塊地只能種$(4\times 25)\times 60/24=250$株，但如果可以對裂區設計的試驗數據建立適當的統計模型，我們同樣可以利用這有限的資源完成試驗并得出結論。在這個例子中稱肥料種類為whole-plot factor，稱水稻品種為sub-plot factor。

對比這個試驗，對于提高紙張的抗拉強度試驗這個例子，我們也可以總結出：

試驗田分為三部分對應的是分三天完成試驗，這既是replicates也是blocking；

三種紙漿制備方法是whole-plot factor；

四種不同的溫度是sub-plot factor；

與區組化析因設計相比，Split-plot設計的factor在每個block中是嵌套（有明顯的順序、從屬關系）而不是交叉的關系；并且Split-plot設計的區組一定是隨機的。

第一種統計模型

GLM procedure

proc glm data=paper; class block method temp; model resp=block method block*method temp block*temp method*temp block*method*temp; random block block*method block*temp block*method*temp; test h=method e=block*method; test h=temp e=block*temp; test h=method*temp e=block*method*temp; run;

這段SAS代碼中，model語句model resp=block method block*method temp blocktemp methodtemp block*method*temp;用來表示block和兩種因素及其所有的交互項，一共是$2^3?1=7$種。random語句random block block*method block*temp block*method*temp;用來指定模型中的隨機項，因為區組是隨機的，包含區組的交互項都是隨機的。

根據這個EMS的結論，要比較紙漿制備方法與溫度及其交互項的效應，分別需要block*method、block*temp、block*method*temp的均方和作為error term，三個test語句就是為了做這些檢驗，結果如下：

這些結果說明在0.1的顯著性水平下，紙漿制備方法與制備使用的溫度對紙張抗拉強度都有顯著影響。

Mixed procedure

proc mixed data=paper method=type1 covtest cl;/*因為隨機項都與區組有關，沒啥特別意義可以不用covtest和cl這兩個命令*/ class block method temp; model resp=method temp method*temp; random block block*method block*temp block*method*temp; run;

紅框內的結果與GLM procedure的test語句的結果相同。

第二種統計模型

與第一種統計模型相比，第二種統計模型去掉了區組與因素的交互項以及sub-plot error，這兩項被計入到random error中。根據第一種統計模型EMS的結果，去掉區組與因素的交互項以及sub-plot error就不能對subplot factor以及whole-plot factor與sub-plot factor的交互項做檢驗。

GLM procedure

proc glm data=paper; class block method temp; model resp=block method block*method temp method*temp; random block block*method; test h=method e=block*method; run;

第二種統計模型只能做制備方法的效應做檢驗，結果是第一種統計模型相同。

Mixed procedure

proc mixed data=paper method=type1; class block method temp; model resp=method temp method*temp; random block block*method; run;

盡管Mixed procedure返回完整的ANOVA，但依然只有紅框內的可以參考，temp與method*temp的結果是基于殘差作為error term計算出來的，與理論結果不一致，不能參考！

總結

以上是生活随笔為你收集整理的Split-plot设计 SAS实践的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。