正在畫流程圖，稍后附上

;x86匯編_用循環結構編程計算階乘n!

code segment ;代碼段開始

assume cs:code,ds:code ;定義代碼段和數據段的段地址都是本段(代碼段)的段地址

org 100h;指定程序被載入內存時的起始地址

start: ;程序開始的標號

push cs;將代碼段地址壓棧

pop ds;從棧中彈出到數據段寄存器,與上句話一起,將代碼段的值賦給數據段

push cs;再將代碼段地址壓棧

pop es;從棧中彈出數據到附加段寄存器

q0:lea dx,tips;q0標號，此處傳遞tips標號的偏移地址到dx

mov ah,9 ;ah=9

int 21h ;調用21h中斷，ah=9時，顯示字符串，字符串從ds:dx到一個$符號結束

q1:mov ah,0; ah = 0

int 16h;調用16h中斷，ah=0時，從鍵盤讀字符，al為字符碼

cmp al,1bh ;將1bh與字符碼比較，1bh是esc的字符碼

jz exit;如果相等，則跳轉到exit標號的位置

cmp al,'0';將al與0的字符碼相比

jb q1 ;如果al

cmp al,'8';將al與8的字符碼相比

ja q1 ;如果al>'8'，跳轉到q1標號的位置

mov ah,0eh; ah=0eh

int 10h;調用10h中斷，ah=0eh時，顯示al表示的字符

sub al,30h;al = al-30h,目的是求出這個字符表示的數值，

or al,al ; al = al | al,與自己作按位或運算，目的是設置標志位

jnz q2 ; 如果結果不是0，也就是說al!=0，則跳轉到標號q2的位置

mov ax,1 ; ax = 1

jmp q4 ; 跳轉到q4的位置

q2:mov ah,0 ;q2標號，ah=0

mov cx,ax ; cx = ax

mov al,1 ; al = 1

xor dx,dx ; dx與自己異或，結果是dx=0,用異或來清0速度比較快！

q3:mul cx ;q3標號，無符號數相乘，(dx,ax)=cx*ax

loop q3 ;cx=cx-1,如果cx不為0，則繼續循環q3標號的操作，

q4:cld ;q4標號 ，方向標志置0

lea di,result ;目的變址寄存器di 設為result標號的偏移地址

add di,2 ; di=di+2

lea bp,table ;基址指針bp設為table標號的偏移地址

mov cx,5 ; cx = 5

q5:xor dx,dx ;q5標號，dx清0

div word ptr [bp] ;ax=(dx,ax)/[bp],求得指定位的值，比如十位百位什么的

or al,30h ;al=al|30h,目的是求這個數的字符，

stosb ; di=al

mov ax,dx ;ax=dx

add bp,2 ;bp=bp+2

loop q5 ;cx=cx-1,如果cx不為0，則繼續循環q5標號的操作，

lea dx,result ;dx 設為result標號的偏移地址

mov ah,9 ;ah=9

int 21h ;調用21h中斷，ah=9時，顯示字符串，字符串從ds:dx到一個$符號結束

jmp q0 ; 跳轉到q0標號的位置

exit: ;exit標號

mov ah,4ch ;ah=4ch

int 21h ;調用21h中斷，ah=4ch時，表示程序退出

;以下內容是預先準備的數據

tips db 'please input a number(0-8),esc to quit: ',0dh,0ah,'$' ;

table dw 10000,1000,100,10,1

result db '!=00000',0dh,0ah,'$'

code ends ;代碼段結束

end start

總結

以上是生活随笔為你收集整理的汇编编程计算机流程图,汇编程序怎么做流程图？的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。