原文地址：https://ethereum.org/token

代幣

我們將要創建一個數字令牌。在以太坊生態系統中數字令牌可以代表任何交易物品：幣，忠誠點，黃金券，白條，游戲物品等。所有令牌都通過標準方式，實現了一些基本功能。這就意味著，你的令牌會立即兼容以太坊錢包和其他客戶端，或使用了相同標準的合約。

最簡單令牌

標準令牌合約會很復雜。但是本質上，實現最基礎的令牌代碼如下：

contract MyToken {
    /* 創建所有賬戶余額數組 */
    mapping (address => uint256) public balanceOf;

    /*初始化合約，將最初的令牌打入創建者的賬戶中*，此處由于官方文檔版本不夠新，沒有public，經驗證是無法正常運行的/
    function MyToken( uint256 initialSupply) public {
        balanceOf[msg.sender] = initialSupply;              // 給創建者所有初始令牌
    }

    /* 發送代幣 */
    function transfer(address _to, uint256 _value) {
        require(balanceOf[msg.sender] >= _value);           // 檢查發送者是否擁有足夠的幣
        require(balanceOf[_to] + _value >= balanceOf[_to]); // 檢查是否越界
        balanceOf[msg.sender] -= _value;                    // 從發送者扣幣
        balanceOf[_to] += _value;                           // 給接受者加相同數額的幣
    }
}

代碼

但如果想復制粘貼更完整一點的代碼，就用這段：

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    // 令牌的公有變量
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals 極力推薦使用默認值，盡量別改
    uint256 public totalSupply;

    // 創建所有賬戶余額數組
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // 在區塊鏈上創建一個公共事件，它觸發就會通知所有客戶端
    event Transfer(address indexed from, address indexed to, uint256 value);

    // 通知客戶端銷毀數額
    event Burn(address indexed from, uint256 value);

    /**
     * 合約方法
     *
     * 初始化合約，將最初的令牌打入創建者的賬戶中
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // 更新總發行量
        balanceOf[msg.sender] = totalSupply;                // 給創建者所有初始令牌
        name = tokenName;                                   // 設置顯示名稱
        symbol = tokenSymbol;                               // 設置顯示縮寫，例如比特幣是BTC
    }

    /**
     * 內部轉賬，只能被該合約調用
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // 如果轉賬到 0x0 地址. 使用 burn() 替代
        require(_to != 0x0);
        // 檢查發送者是否擁有足夠的幣
        require(balanceOf[_from] >= _value);
        // 檢查越界
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // 將此信息保存用于將來確認
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // 從發送者扣幣
        balanceOf[_from] -= _value;
        // 給接收者加相同數量幣
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        // 使用assert是為了使用靜態分析找到代碼bug. 它永遠不會失敗
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * 發送令牌
     *
     * 從你的賬戶發送個`_value` 令牌到 `_to` 
     *
     * @param _to 接收地址
     * @param _value 發送數量
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * 從其他地址發送令牌
     *
     * 從`_from` 發送 `_value` 個令牌到 `_to` 
     *
     * @param _from 發送地址
     * @param _to 接收地址
     * @param _value 發送數量
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * 設置其他地址限額
     *
     * 允許 `_spender` 以你的名義使用不超過 `_value`令牌 
     *
     * @param _spender 授權使用的地址
     * @param _value 最大可使用數量
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * 設置其他地址限額，并通知
     *
     * 允許 `_spender`以你的名義使用最多 `_value`個令牌, 然后通知合約
     *
     * @param _spender 授權使用的地址
     * @param _value  最大使用額度
     * @param _extraData 發送給已經證明的合約額外信息
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * 銷毀令牌
     *
     * 永久除去 `_value` 個令牌，不可恢復
     *
     * @param _value 數量
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        Burn(msg.sender, _value);
        return true;
    }

    /**
     * 從其他賬戶銷毀令牌
     *
     * 以‘_from’的名義，移除其 `_value`個令牌，不可恢復.
     *
     * @param _from 地址
     * @param _value 銷毀數量
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        Burn(_from, _value);
        return true;
    }
}

給我的ETH捐贈地址：0xdc834D429b3098f0568Af873c2d73b08790BF677

創建自己的加密貨幣MNC——以太坊代幣（二）

創建自己的區塊鏈游戲SLOT——以太坊代幣（三）

總結

以上是生活随笔為你收集整理的创建自己的加密货币——以太坊代币（一）的全部內容，希望文章能夠幫你解決所遇到的問題。

如果覺得生活随笔網站內容還不錯，歡迎將生活随笔推薦給好友。